Making RSS downloader work with mininova using WinXP and ASP

[abud]

Hi,

Here is an asp script that can be used as an alternative to rssatellite and php scripts found here.

Hope it helps windows user that are not familiar with rssatellite.

Any feedback if you try it would be appreciated. Been working very well so far over here...

<% 
'
' This script was made by aBud 2007.10.28
'
' Special thanks for this web site help
' http://classicasp.aspfaq.com/general/how-do-i-read-the-contents-of-a-remote-web-page.html
' 
' This simple ASP script can be used to modify the source test of an RSS feed.
' 
' For example mininova RSS feeds are incompatible with torrent 
' clients like uTorrent because they do not link directly to 
' the torrent file. This prevent the use of the uTorrent RSS Downloader to  
' automate the download of your favorite episodes. To make it work the RSS    
' page needs to be modified by replacing /tor/ by /get/ inside links contained 
' in the page.
'
' Simply install IIS available on Windows XP and copy this file 
' in your IIS wwwroot folder. This page uses MSXML that can be 
' downloaded thru windows update.
' 
' Next, change your RSS favorite link in uTorrent 
' from
' Back to you|http://www.mininova.org/rss/back+to+you+eztv
' to
' Back to you|http://127.0.0.1/default.asp?url=http://www.mininova.org/rss/back+to+you+eztv
'
' Now you will be able to download mininova releases directly from your torrent client.
' Be patient if you don't get all your link refresh in 1 download
' mininova site timeout sometimes. Try to refresh at a later time.
'
' If anyone can figure out why uTorrent reports HTTP Error 403 and have a solution to it
' email me at abudx@icqmail.com.
'
' You may want to change your IE setting Check for newer version of stored pages
' to "Every visit to the page" when you test this page in your browser.
'
        ' Get the url passed as a parameter
    url = Request.QueryString("url")

    ' Retreive the content of the page using MSXML object
    br = Request.ServerVariables("HTTP_USER_AGENT") 
    set xmlhttp = CreateObject("MSXML2.ServerXMLHTTP")  
    on error resume next 
    xmlhttp.open "GET", url, false 
    xmlhttp.setRequestHeader "User-Agent", br 
    xmlhttp.send ""  

    ' Check if there is an error
    if err.number = 0 then 

            ' Based on the url, make the proper replacement
            ' Add your specific relacement here
            if instr(url,"mininova")>0 then 
                rssfields = Replace(xmlhttp.responseText, "/tor/", "/get/")
            else
                rssfields = xmlhttp.responseText
            end if

        'Display the modified page for your torrent client
        response.write rssfields
    else
        'An error occured while accessing the page 
        'Invalid URL or Timeout?
        'Test your link directly in the browser
      response.write "An error occured while refreshing the page.<br>Invalid URL or Timeout?"
    end if 

    'Happend the url and a timestamp to the page for testing purpose
    response.write "<br>" & url & " - " & date & " " & time

    set xmlhttp = nothing 
%>